作為一個(gè)新特性，F(xiàn)lash Builder 4已經(jīng)集成FlexUnit Test，使用起來(lái)很方便，下面我們就以一個(gè)Case來(lái)談?wù)勗鯓釉贔lash Builder 4中進(jìn)行Unit Test。

1. 準(zhǔn)備工作。首先用Flash Builder 4在一個(gè)Flex工程新建一個(gè)類(lèi)。如下面代碼。

    package
{
	import flash.utils.ByteArray;

	public class ObjectUtil
	{
		public static function clone(source:*):* 
		{
			var ba:ByteArray = new ByteArray();
			ba.writeObject(source);
			ba.position = 0;
			return ba.readObject();
		}
	}
}
  

這個(gè)工具類(lèi)實(shí)現(xiàn)對(duì)象的深度clone，也就是被復(fù)制的目標(biāo)對(duì)象不再是源對(duì)象的參照，改變目標(biāo)對(duì)象不會(huì)影響源對(duì)象。因?yàn)锳ctionScript 3.0和Flex Framework中有不少內(nèi)置對(duì)象，如Date、Object、Array、ArrayColection、BitmapData等，情況比較多，單元測(cè)試正好派上用場(chǎng)。

2. 創(chuàng)建新的FlexUnit TestCase 類(lèi)。

選擇該類(lèi)＞新建＞TestCase 類(lèi)，打開(kāi)下圖所示對(duì)話(huà)框，一般按默認(rèn)設(shè)置就行了。如下圖所示。

選擇應(yīng)為其生成測(cè)試方法存根的方法。如下圖所示。

Flash Builder 4將自動(dòng)為我們生成TestCase類(lèi)和主程序文件的結(jié)構(gòu)代碼。在TestCase類(lèi)中，已經(jīng)有一個(gè)沒(méi)有實(shí)現(xiàn)的測(cè)試方法testClone，為方便錯(cuò)誤跟蹤，我們修改成了四個(gè)測(cè)試方。如下代碼所示。

    public function testCloneObject():void
{
	var obj:Object= {name:"Jim", age:25}
	var newObj:Object = ObjectUtil.clone(obj);
	newObj.age = 28;
	assertObjectEquals(obj, {name:"Jim", age:25});
}

public function testCloneArray():void
{
	var arr:Array= [1,2];			
	var newArr:Array = ObjectUtil.clone(arr);
	newArr[1] = 3;
	assertObjectEquals(arr, [1,2]);
}

public function testCloneCollection():void
{
	var ac:ArrayCollection = new ArrayCollection([
		{name:"Jim", age:28},
		{name:"Tom", age:30}
	]);
	
	var newAC:ArrayCollection = ObjectUtil.clone(ac);
	newAC.getItemAt(0).name = "Kite";
	assertEquals(ac.getItemAt(0).name, "Jim");
}

public function testBitmapData():void
{
	var bmd:BitmapData = new BitmapData(100,100,false);
	bmd.setPixel(10,10,0xFF0000);
	var newBMD:BitmapData = ObjectUtil.clone(bmd);
	newBMD.setPixel(10,10,0x0000FF);;
	assertEquals(bmd.getPixel(10,10), 0xFF0000);
}
  

注意，在FlexUnit 1 test中, 每個(gè)你創(chuàng)建的方法的方法名都必須以test開(kāi)頭, 這個(gè)是為了讓測(cè)試運(yùn)行器辨識(shí)需要測(cè)試的方法。

3. 創(chuàng)建新的FlexUnit Test Suite 類(lèi)。選擇該類(lèi)＞新建＞TestSuie類(lèi)，打開(kāi)對(duì)話(huà)框，輸入TestSuie類(lèi)名，選擇目標(biāo)測(cè)試類(lèi)和方法。如下圖所示。

4. 修改主程序。

打開(kāi)主程序mxml，做如下修改。

    <?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
	xmlns:s="library://ns.adobe.com/flex/spark" 
	xmlns:flexui="flexunit.flexui.*"
	xmlns:mx="library://ns.adobe.com/flex/halo" minWidth="800" minHeight="600"
	creationComplete="creationCompleteHandler()">	
	<fx:Script>
	<![CDATA[
		import flexUnitTests.UtilSuite;
		
		private var flexUnitTests_UtilSuite_obj:flexUnitTests.UtilSuite;
		
		protected function creationCompleteHandler():void
		{
			testRunner.test = UtilSuite.suite();
			testRunner.startTest();
		}
	]]>
	</fx:Script>
	
	<flexui:TestRunnerBase id="testRunner"
		width="100%" height="100%"/>

</s:Application>
  

5. 運(yùn)行測(cè)試程序。

結(jié)果testBitmapData()方法測(cè)試失敗：TypeError: Error #1034: 強(qiáng)制轉(zhuǎn)換類(lèi)型失敗:無(wú)法將 Object@b9b5fb1 轉(zhuǎn)換為 flash.display.BitmapData。

6. 修改錯(cuò)誤。其實(shí)，BitmapData有自己的clone方法，我們只要將這個(gè)方法整合到ObjectUtil類(lèi)中就行了。

打開(kāi)ObjectUtil類(lèi)，添加一個(gè)條件，最終代碼如下。

    public static function clone(source:*):* 
{
	var ba:ByteArray = new ByteArray();
	ba.writeObject(source);
	ba.position = 0;
	if(source is BitmapData)
	{
		return (source as BitmapData).clone();
	}
	return ba.readObject();
}
  

回到第五步再進(jìn)行測(cè)試，直到全部方法都通過(guò)。

另外，F(xiàn)lexUnit 4 test所用代碼更簡(jiǎn)單，還支持元數(shù)據(jù)標(biāo)簽。通過(guò)運(yùn)行方式＞FlexUnit 測(cè)試，可以直接生成主程序代碼。FlexUnit 4 test的界面是總結(jié)性的，很簡(jiǎn)單，還有就是FlexUnit 面版，大家有空可以試一下。

使用Flash Builder 4進(jìn)行Unit Test